GM Tailor (30 - GM, Automated)

Discussion in 'Guides' started by Skydancer, Aug 16, 2021.

  1. Skydancer

    Skydancer Active Member

    Joined:
    Feb 12, 2018
    Messages:
    195
    Likes Received:
    102
    This is a small piece of a much larger script that I have been working on. The script below will take you from 30-GM Tailoring.

    Step 0. Use ClassicUO.
    Step 1a. Train snooping until you have 50 dex.
    Step 1b. Train tailoring with a Guildmaster.
    Step 1c. Buy a tan book (type 4080) and a pair of scissors from a provisioner. Keep them in your backpack.

    Step 2a. Go to Razor > Scripts > Options.
    Step 2b. Create a variable in Razor for the container that you wish to restock from.
    Step 2c. Name your variable GM Tailor.

    Step 3. Razor Counters: Required. Spelling Matters.
    Bandages
    Sewing Kit
    ClothB
    (For bolts of cloth)
    ClothC (For cut cloth)
    Leather (For cut leather)

    Step 4a. Set Organizer 1 to move bandages. Hotbag doesn't matter. The script will set it for you.
    Step 4b. Set Restock 1 to grab a single sewing kit and a single bolt of cloth.

    Step 5. Lock down GM Tailor in your house and load it with 100~ sewing kits and 25k yards cloth bolts.
    Step 6. Place a single sewing kit in your backpack.
    Step 7. Create a script with Razor and copy/paste/save the text below.
    Step 8. Hit play.

    Edit -- I have only run this to about 85 tailoring, so it hasn't actually been tested all the way through yet. If tailoring can't actually be GM'd on leather gloves, then this won't go all the way to GM yet. I'll patch it as soon as I know when/where it needs to make the jump to gorgets.

    Code:
    if findtype 'sewing kit' backpack
        organizer 1 'set'
        waitfortarget
        target 'GM Tailor'
        wait 1000
        if findtype '4080' backpack
            dclicktype 'sewing kit' backpack
            waitforgump 'any'
            while skill 'tailoring' < 100
                while findtype '3989' backpack or findtype 'short pants' backpack or findtype 'fancy dress' backpack or findtype 'cloak' backpack or findtype 'robe' backpack or findtype '5981' backpack or findtype 'leather gloves' backpack or findtype 'leather gorget' backpack
                    dclicktype 'scissors' backpack
                    waitfortarget
                    if findtype '3989' backpack
                        targettype '3989' backpack
                    elseif findtype 'short pants' backpack
                        targettype 'short pants' backpack
                    elseif findtype 'fancy dress' backpack
                        targettype 'fancy dress' backpack
                    elseif findtype 'cloak' backpack
                        targettype 'cloak' backpack
                    elseif findtype 'robe' backpack
                        targettype 'robe' backpack
                    elseif findtype '5981' backpack
                        targettype '5981' backpack
                        wait 1000
                        if count 'Bandages' > 50
                            organizer 1
                        endif
                    elseif findtype 'leather gloves' backpack
                        targettype 'leather gloves' backpack
                    elseif findtype 'leather gorget' backpack
                        targettype 'leather gorget' backpack
                    endif
                    wait 1000
                endwhile
                if skill 'tailoring' < 49.8
                    gumpresponse 15
                    waitforgump 'any'
                    gumpresponse 2
                elseif skill 'tailoring' < 51.8
                    gumpresponse 8
                    waitforgump 'any'
                    gumpresponse 44
                elseif skill 'tailoring' < 57.9
                    gumpresponse 8
                    waitforgump 'any'
                    gumpresponse 51
                elseif skill 'tailoring' < 74.6
                    gumpresponse 8
                    waitforgump 'any'
                    gumpresponse 58
                elseif skill 'tailoring' < 99.4
                    gumpresponse 22
                    waitforgump 'any'
                    gumpresponse 23
                elseif skill 'tailoring' < 100
                    gumpresponse 36
                    waitforgump 'any'
                    gumpresponse 16
                else
                    sysmsg "Grandmater Tailor."
                    stop
                endif
                waitforgump 'any' 6000
                if count 'Sewing Kit' = 0
                    restock 1
                    waitfortarget
                    target 'GM Tailor'
                    wait 2000
                    dclicktype 'sewing kit' backpack
                    waitforgump 'any'
                endif
                if skill 'tailoring' < 99.4
                    if count 'ClothB' < 1 and count 'ClothC' < 50
                        restock 1
                        waitfortarget
                        target 'GM Tailor'
                        wait 2000
                    endif
                elseif skill 'tailoring' < 100
                    if count 'Leather' < 50
                        restock 1
                        waitfortarget
                        target 'GM Tailor'
                        wait 2000
                    endif
                else
                    sysmsg "This line should never be called"
                endif
                if insysmsg 'The world will save'
                    while not insysmsg 'World save complete'
                        wait 5000
                    endwhile
                endif         
            endwhile
        else
            sysmsg "Non 4080 Run"
        endif
    endif
    #
    
    Last edited: Aug 16, 2021
  2. JohnM

    JohnM Well-Known Member
    UO:R Donor

    Joined:
    Mar 27, 2015
    Messages:
    1,898
    Likes Received:
    1,313
    Thanks for the script. I made a couple of adjustments

    At 99.4, you need to make studded gorgets, not leather gorgets. I also removed leather gloves

Share This Page